{
  inputs,
  system,
  user,
  userFullname,
  ...
}: modules: home-modules:
with inputs;
  nixpkgs.lib.nixosSystem {
    specialArgs = {inherit inputs;};

    inherit system;

    modules =
      modules
      ++ [
        stylix.nixosModules.stylix
        home-manager.nixosModules.home-manager
        {
          home-manager = {
            useGlobalPkgs = true;
            useUserPackages = true;
            users.${user}.imports =
              home-modules
              ++ [
                hyprland.homeManagerModules.default
                ../home/.
                {
                  options.home.userFullname = nixpkgs.lib.mkOption {default = userFullname;};
                  config.home.username = user;
                }
              ];
          };
          nixpkgs.config.packageOverrides = pkgs: {
            hycov = hycov.packages.${system}.hycov;
          };
          imports = [
            {
              options.user = nixpkgs.lib.mkOption {default = user;};
            }
            ../nixos/.
          ];
        }
      ];
  }