{
  description = "A flake using my config";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";
    stable-nixpkgs.url = "nixpkgs/nixos-23.11";
    home-manager = {
      url = "github:nix-community/home-manager/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    stylix.url = "github:danth/stylix";
    hyprland.url = "github:hyprwm/Hyprland/v0.35.0";
  };

  outputs = inputs: let
    system = "x86_64-linux";
    pkgs = import inputs.nixpkgs {
      inherit system;
      overlays = [inputs.hyprland.overlays];
    };
    user = "tristan";
    userFullname = "Tristan Beedell";
    auto-login = import ./nixos/programs/auto-login.nix;

    mkConf = import ./lib/mkconf.nix {inherit inputs system user userFullname;};
  in {
    formatter.${system} = pkgs.alejandra;
    nixosConfigurations = {
      zenix =
        mkConf [
          ./hardware/zenix.nix
          (auto-login "Hyprland")
          ./nixos/programs/gamer.nix
          ./nixos/programs/personal.nix
          ./nixos/programs/anki.nix
          ./nixos/workstation.nix
        ] [
          ./home/desktop/hyprland/.
          ./home/programs/graphical.nix
          ./home/programs/gamer.nix
          ./home/programs/personal/.
        ];

      FCS-Tristan-Nixbook =
        mkConf [
          ./hardware/fcs-tristan-nixbook.nix
          (auto-login "Hyprland")
          ./nixos/modules/work.nix
          ./nixos/workstation.nix
        ] [
          ./home/desktop/hyprland/.
          ./home/programs/work.nix
          ./home/programs/graphical.nix
        ];

      alpine = mkConf [
        ./hardware/alpine.nix
        ./nixos/programs/anki.nix
      ] [];

      vm-sway =
        builtins.trace ''
          use super+enter to start a terminal.
          use super+d to launch applications

          start the vm with '-vga qxl' or '-vga virtio'
        ''
        mkConf
        [
          ./hardware/vm.nix
          (auto-login "sway")
        ] [
          ./home/desktop/sway/.
        ];

      vm-hyprland =
        builtins.trace ''
          use super+enter to start a terminal.
          use super+d to launch applications

          Hyprland is VERY SLOW in the VM.

          start with '-vga virtio'
        ''
        mkConf
        [
          ./hardware/vm.nix
          (./nixos/programs/auto-login.nix "Hyprland")
        ] [
          ./home/desktop/hyprland/.
        ];

      vm-tty = mkConf [
        ./hardware/vm.nix
      ] [];
    };
  };
}