{
  config,
  pkgs,
  ...
}: let
  modifier = config.windowManager.modifierKey;
  browser = "${pkgs.brave}/opt/brave.com/brave/brave-browser";
  pwa = {
    slack = "mpagibdhafmlkgpemeicgogjnhclenoc";
    teams = "cifhbcnohmdccbgoicgdjpfamggdegmo";
  };
in {
  roles.email = {
    enable = true;
    email = "tristan.beedell@cryoserver.com";
    terminal = false;
  };

  home.packages = [
    pkgs.thunderbird
    pkgs.remmina
    pkgs.devcontainer
    (import ../../lib/mkapp.nix "slack" {
      inherit pkgs browser;
      desktopName = "Slack";
      app-id = pwa.slack;
    })
    (import ../../lib/mkapp.nix "teams" {
      inherit pkgs browser;
      app-id = pwa.teams;
      desktopName = "Microsoft Teams";
    })
  ];

  home.sessionVariables = {
    CYPRESS_INSTALL_BINARY = 0;
    CYPRESS_RUN_BINARY = "${pkgs.cypress}/bin/Cypress";
    MONGOMS_SYSTEM_BINARY = "${pkgs.callPackage ../../pkgs/mongodb.nix pkgs}/bin/mongod";
  };

  gtk.gtk3.bookmarks = [
    "file:///home/tristan/OneDrive/ OneDrive"
  ];

  programs.vscode = {
    package = pkgs.vscode;
    extensions = with pkgs; [
      vscode-extensions.ms-azuretools.vscode-docker
    ];
    userSettings = {
      "aws.telemetry" = false;
      "gitlens.telemetry.enabled" = false;
      "redhat.telemetry.enabled" = false;
    };
  };

  wayland.windowManager.hyprland.settings = {
    bind = [
      "${modifier}, e, focuswindow, thunderbird"
      "${modifier}, t, focuswindow, brave-${pwa.teams}-Profile_2"
      "${modifier}, s, focuswindow, brave-${pwa.slack}-Profile_2"
    ];
  };
}