{ lib, fetchFromGitHub, cmake, curl, xorg, avahi, stdenv, pkgs,
  openssl, wrapGAppsHook,
  avahiWithLibdnssdCompat ? avahi.override { withLibdnssdCompat = true; },
  fetchpatch
}:

stdenv.mkDerivation rec {
  pname = "barrier";
  version = "2.4.0";

  src = fetchFromGitHub {
    owner = "input-leap";
    repo = "input-leap";
    rev = "v${version}";
    sha256 = "sha256-2tHqLF3zS3C4UnOVIZfpcuzaemC9++nC7lXgFnFSfKU=";
    fetchSubmodules = true;
  };

  patches = [
    # This patch can be removed when a new version of barrier (greater than 2.4.0)
    # is released, which will contain this commit.
    (fetchpatch {
      name = "add-missing-cstddef-header.patch";
      url = "https://github.com/debauchee/barrier/commit/4b12265ae5d324b942698a3177e1d8b1749414d7.patch";
      sha256 = "sha256-ajMxP7szBFi4h8cMT3qswfa3k/QiJ1FGI3q9fkCFQQk=";
    })
  ];

  buildInputs = [ curl xorg.libX11 xorg.libXext xorg.libXtst avahiWithLibdnssdCompat pkgs.libsForQt5.qt5.qtbase ];
  nativeBuildInputs = [ cmake wrapGAppsHook pkgs.libsForQt5.qt5.wrapQtAppsHook ];

  postFixup = ''
    substituteInPlace "$out/share/applications/barrier.desktop" --replace "Exec=barrier" "Exec=$out/bin/barrier"
  '';

  qtWrapperArgs = [
    ''--prefix PATH : ${lib.makeBinPath [ openssl ]}''
  ];

  meta = {
    description = "Open-source KVM software";
    longDescription = ''
      Input Leap is software that mimics the functionality of a KVM switch,
      which historically would allow you to use a single keyboard and mouse
      to control multiple computers by physically turning a dial on the box
      to switch the machine you're controlling at any given moment. Input
      Leap does this in software, allowing you to tell it which machine to
      control by moving your mouse to the edge of the screen, or by using a
      keypress to switch focus to a different system.
    '';
    homepage = "https://github.com/input-leap/input-leap";
    downloadPage = "https://github.com/input-leap/input-leap/releases";
    license = lib.licenses.gpl2;
    maintainers = [ lib.maintainers.phryneas ];
    platforms = lib.platforms.linux;
  };
}