{
  description = "A flake using my config";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";
    stable-nixpkgs.url = "nixpkgs/nixos-23.11";
    home-manager = {
      url = "github:nix-community/home-manager/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    stylix.url = "github:danth/stylix";
    hyprland.url = "github:hyprwm/Hyprland";
    hycov = {
      url = "github:DreamMaoMao/hycov";
      inputs.hyprland.follows = "hyprland";
    };
  };

  outputs = inputs: let
    system = "x86_64-linux";
    pkgs = import inputs.nixpkgs {inherit system;};
    user = "tristan";
    userFullname = "Tristan Beedell";

    mkConf = import ./lib/mkconf.nix {inherit inputs system user userFullname;};
  in {
    formatter.${system} = pkgs.alejandra;
    nixosConfigurations = {
      zenix =
        mkConf [
          ./hardware/zenix.nix
          ./nixos/programs/hyprland.nix
          ./nixos/programs/gamer.nix
          ./nixos/programs/personal.nix
        ] [
          ./home/programs/gamer.nix
          ./home/programs/personal.nix
        ];

      FCS-Tristan-Nixbook =
        mkConf [
          ./hardware/fcs-tristan-nixbook.nix
          ./nixos/programs/hyprland.nix
          ./nixos/modules/work.nix
        ] [
          ./home/programs/work.nix
        ];

      vm-sway =
        builtins.trace ''
          use super+enter to start a terminal.
          use super+d to launch applications

          start the vm with '-vga qxl' or '-vga virtio'
        ''
        mkConf
        [
          ./hardware/vm.nix
          ./nixos/programs/sway.nix
        ] [];

      vm-hyprland =
        builtins.trace ''
          use super+enter to start a terminal.
          use super+d to launch applications

          Hyprland is VERY SLOW in the VM.

          start with '-vga virtio'
        ''
        mkConf
        [
          ./hardware/vm.nix
          ./nixos/programs/hyprland.nix
        ] [];

      vm-tty = mkConf [
        ./hardware/vm.nix
      ] [];
    };
  };
}