{
  inputs,
  system,
  user,
  userFullname,
  ...
}: modules: home-modules:
with inputs;
  nixpkgs.lib.nixosSystem {
    specialArgs = {inherit inputs;};

    inherit system;

    modules =
      modules
      ++ [
        stylix.nixosModules.stylix
        home-manager.nixosModules.home-manager
        {
          home-manager = {
            useGlobalPkgs = true;
            useUserPackages = true;
            users.${user}.imports =
              home-modules
              ++ [
                ../home/.
                {
                  options.home.userFullname = nixpkgs.lib.mkOption {default = userFullname;};
                  config.home.username = user;
                }
              ];
          };
          programs.hyprland.package = hyprland.packages."${system}".hyprland;
          nixpkgs.config.packageOverrides = pkgs: {
            inherit (hyprland.packages.${system}) xdg-desktop-portal-hyprland hyprland hyprland-protocols;
            hycov = hycov.packages.${system}.hycov;
            brave = (import stable-nixpkgs {inherit system;}).brave;
          };
          imports = [
            {
              options.user = nixpkgs.lib.mkOption {default = user;};
            }
            ../nixos/.
          ];
        }
      ];
  }